home *** CD-ROM | disk | FTP | other *** search
/ Atari Mega Archive 2 / Atari Mega Archive CD - Volume 2.iso / 8bit / cislib_b / rmdsk2.asm < prev    next >
Assembly Source File  |  1995-04-22  |  11KB  |  457 lines
  1.          .TAB 11,15,27 
  2.          .SET 1,7 
  3.          .TITLE "RAMDISK FOR FMS VERSION 2             05-25-85" 
  4. ; 
  5. ********* ZERO PAGE ********** 
  6. ; 
  7. RTCLKL   =   $14 
  8. BUFRL    =   $32     ;SIO ZPG, CAN USE 
  9. BFENL    =   $34     ;SIO ZPG, CAN USE 
  10. ; 
  11. ******** OTHER RAM *********** 
  12. ; 
  13. INITAD   =   $02E2 
  14. DVSTAT   =   $02EA 
  15. DRVBYT   =   $070A   ;DRIVE BITS 
  16. SASA     =   $070C   ;END FMS CODE 
  17. DSIO4    =   $07A2   ;FMS 2 SIO CALL 
  18. FMSINIT  =   $07E0 
  19. DIHCL    =   $0816   ;FMS 2 NORM STAT CALL 
  20. WRTDOS   =   $120A   ;FMS 2 WRITE DOS ENTRY 
  21. ERDVDC   =   $12BF   ;FMS INVALID CMD ERR 
  22. TSTLC    =   $4000   ;EXTRA RAMS 
  23. VTOCP    =   $7200   ;XRAM VTOC 
  24. RDIHCL   =   $E536   ;DOSXL.XL STAT CALL 
  25. ; 
  26. ********** OS ROM ************* 
  27. ; 
  28. DHADR    =   $E453   ;OS RES DISK 
  29. SIOV     =   $E459   ;SIO ENTRY ADDR 
  30. ; 
  31. ********* CONSTANT ************ 
  32. ; 
  33. RAMDRV   =   4       ;DRIVE # OF RAMDISK 
  34. ; 
  35. ****** I/O REGISTERS ********** 
  36. ; 
  37. PORTB    =   $D301 
  38. NMIEN    =   $D40E 
  39. ; 
  40. ; 
  41. *********** DCB *************** 
  42. ; 
  43. ; 
  44. DDEVIC   =   $0300   ;SERIAL BUS ID 
  45. DUNIT    =   $0301   ;UNIT NUMBER 
  46. DCOMND   =   $0302   ;COMMAND 
  47. DSTATS   =   $0303   ;DIRECTION/STATUS 
  48. DBUFLO   =   $0304   ;BUF ADDR LO 
  49. DBUFHI   =   $0305   ;         HI 
  50. ; 
  51. ; 
  52. DAUX1    =   $030A   ;DEVICE INFO (SECT LO) 
  53. DAUX2    =   $030B   ;  "     "   (     HI) 
  54. ; 
  55. ; 
  56. ; 
  57. ; 
  58. ******                 ********* 
  59. ****** RAMDISK HANDLER ********* 
  60. ******                 ********* 
  61. ; 
  62.          *=  $3800   ;WILL RELOCATE 
  63. ; 
  64. ; SIO CALL TO HERE 
  65. ; 
  66. SECIO    LDA DUNIT 
  67.          CMP #RAMDRV 
  68.          BEQ SECIO1 
  69.          JMP SIOV 
  70. ; 
  71. SECIO1   LDA DAUX2   ;HI SECT 
  72.          CMP #2 
  73.          BCC TGSEC   ;IN RANGE 
  74.          BNE BDSEC   ;RIDICULOUS 
  75.          LDA DAUX1 
  76.          CMP #4 
  77.          BCC TGSEC   ;BR IF < 516 
  78. ; 
  79. BDSEC    LDY #144 
  80.          STY DSTATS 
  81.          RTS  
  82. ; 
  83. TGSEC    LDA DAUX2 
  84.          BNE NRMSC   ;BR IF SEC> 255 
  85. ; 
  86. TSCLO    LDA DAUX1 
  87.          CMP #4      ;HI WAS ZERO 
  88.          BCS NRMSC   ;DO TRANS IF 4+ 
  89.          LDY #1 
  90.          STY DSTATS  ;ELSE LIE 
  91.          RTS  
  92. ; 
  93. NRMSC    SEC         ;READY TRANSFER 
  94.          LDA DAUX1   ;SECTOR LO 
  95.          SBC #4 
  96.          STA BFENL   ;RAMDISK 4 THRU 515 
  97.          LDA DAUX2 
  98.          SBC #0 
  99.          ASL BFENL   ;EXTRA RAM PG UPPER 
  100.          ROL A       ;2 BITS 
  101.          ASL A 
  102.          ASL A 
  103.          STA BFENL+1 ;AT BITS 2 AND 3 
  104.          LDX RTCLKL 
  105. WVLP     CPX RTCLKL 
  106.          BEQ WVLP    ;WAIT 'TIL END VBLANK 
  107.          LDA #0 
  108.          STA NMIEN   ;TURN OFF NMI 
  109.          SEI         ;     AND IRQ 
  110.          LDA PORTB   ;MEM CONTROL 
  111.          TAX         ;NORM IN X 
  112.          AND #$E3 
  113.          ORA BFENL+1 
  114.          PHA         ;RMDSK ON STACK 
  115.          LDA BFENL   ;SECT # REMAINDER 
  116.          SEC         ;+ $40 (WILL BE) 
  117.          ROR A 
  118.          LSR A       ;LSB TO C 
  119.          STA BFENL+1 ;IS HIGH ADDR 
  120.          LDA #0 
  121.          ROR A       ;SECT LSB = 128 BYTES 
  122.          STA BFENL 
  123.          LDA DBUFLO 
  124.          STA BUFRL   ;SET I/O ADDRESS 
  125.          LDA DBUFHI 
  126.          STA BUFRL+1 
  127.          LDY #127 
  128.          LDA DSTATS 
  129.          BMI SCWRT   ;BR IF 'TO DISK' 
  130. SECRD    PLA         ;ELSE 
  131.          PHA  
  132.          STA PORTB   ;RMDSK 
  133.          LDA (BFENL),Y ;IS SOURCE 
  134.          STX PORTB   ;NORM 
  135.          STA (BUFRL),Y ;IS DEST 
  136.          DEY  
  137.          BPL SECRD 
  138.          BMI SCDON 
  139. ; 
  140. SCWRT    PLA         ;FOR WRITE, 
  141.          STX PORTB 
  142.          TAX         ;SWAP SO THAT 
  143.          LDA PORTB 
  144.          PHA  
  145. SCWT1    PLA  
  146.          PHA  
  147.          STA PORTB   ;NORM 
  148.          LDA (BUFRL),Y ;IS SOURCE 
  149.          STX PORTB   ;RMDSK 
  150.          STA (BFENL),Y ;IS DEST 
  151.          DEY  
  152.          BPL SCWT1 
  153. ; 
  154.          TXA  
  155.          AND #$0C 
  156.          CMP #8      ;VTOC BANK? 
  157.          BNE SCDON   ;BR NO 
  158.          LDX #1 
  159.          CPX VTOCP+2 ;TEST MAXSEC HI 
  160.          BEQ SCDON   ;ASSUME OK 
  161.          LDA VTOCP+3 
  162.          SBC #707-504 ;ALSO BORROW 
  163.          BCS SCWT2 
  164.          DEC VTOCP+4 
  165.          BPL SCWT2 
  166.          LDA #0 
  167.          STA VTOCP+4 
  168. SCWT2    STA VTOCP+3 ;FREE SECTS 
  169.          STX VTOCP+2 
  170.          LDA #$F7 
  171.          STA VTOCP+1 ;& MAX SECTS 
  172. ; 
  173. SCDON    PLA         ;FIX STACK 
  174.          LDA PORTB 
  175.          AND #$E3 
  176.          ORA #$1C 
  177.          STA PORTB   ;NORM 
  178.          LDA #$C0 
  179.          STA NMIEN   ;ENABLE NMI 
  180.          CLI         ;   AND IRQ 
  181.          LDA #0 
  182.          LDY #1 
  183.          STY DSTATS  ;AFFIRM GOOD 
  184.          RTS  
  185. ; 
  186. SCIOLN   =   *-SECIO 
  187. ; 
  188. ********* DRIVE STATUS ******** 
  189. ; 
  190. DRSTAT   LDA DUNIT 
  191.          CMP #RAMDRV 
  192.          BEQ RMSTA 
  193.          JMP DHADR 
  194. ; 
  195. RMSTA    LDA #0 
  196.          STA DVSTAT 
  197.          STA DVSTAT+1 
  198.          STA DVSTAT+3 
  199.          LDY #1 
  200.          STY DVSTAT+2 ;128 BYTE SECTS 
  201.          RTS  
  202. ; 
  203. RELEN    =   *-SECIO ;RELOCATE LENGTH 
  204. ; 
  205. ; 
  206. ; 
  207. *****                      ***** 
  208. ***** INSTALLATION ROUTINE ***** 
  209. *****                      ***** 
  210. ; 
  211. INSTALL  LDA DSIO4+1 ;SIO CALL? 
  212.          CMP # <SIOV 
  213.          BNE NOPE 
  214.          LDA DSIO4+2 
  215.          CMP # >SIOV 
  216.          BNE NOPE 
  217. ; 
  218. ******* 130XE TEST ********* 
  219. ; 
  220.          LDA PORTB 
  221.          TAX         ;SAVE NORM CONFIG 
  222.          AND #$EF 
  223.          TAY         ;SAVE EXTRA CONFIG 
  224.          STY PORTB 
  225.          LDA TSTLC   ;GET EXTRA BYTE 
  226.          STX PORTB   ;SET NORM 
  227.          CMP TSTLC 
  228.          BNE CNTIN   ;BR IF EXTRA 
  229.          LDA TSTLC 
  230.          EOR #$FF    ;COMPLEMENT NORM 
  231.          STA TSTLC 
  232.          STY PORTB   ;SET EXTRA 
  233.          CMP TSTLC 
  234.          PHP         ;SAVE COMPARE RESULT 
  235.          STX PORTB 
  236.          EOR #$FF    ;UNCOMPLEMENT 
  237.          STA TSTLC   ;& REPAIR NORM 
  238.          PLP  
  239.          BNE CNTIN   ;BR IF EXTRA 
  240. NOPE     JMP NONE 
  241. ; 
  242. CNTIN    LDA DIHCL+1 ;NORM V2 STAT CALL? 
  243.          CMP # <DHADR 
  244.          BNE NOTLO 
  245.          LDA DIHCL+2 
  246.          CMP # >DHADR 
  247.          BEQ DS2LO   ;IF SO, CAN INSTALL 
  248. ; 
  249. NOTLO    LDA #0      ;ELSE DOSXL.XL STAT CALL? 
  250.          LDX RTCLKL 
  251. IVBLP    CPX RTCLKL 
  252.          BEQ IVBLP 
  253.          STA NMIEN 
  254.          SEI  
  255.          LDA PORTB 
  256.          AND #$FE 
  257.          STA PORTB 
  258.          LDA RDIHCL+1 
  259.          CMP # <DHADR 
  260.          BNE NOTFN 
  261.          LDA RDIHCL+2 
  262.          CMP # >DHADR 
  263.          BNE NOTFN 
  264.          JSR COPYDOWN ;YES...DO MOVE 
  265.          LDA DRSADR  ;& REPLACE STAT CALL 
  266.          STA RDIHCL+1 
  267.          LDA DRSADR+1 
  268.          STA RDIHCL+2 
  269.          LDA PORTB 
  270.          ORA #1 
  271.          STA PORTB 
  272.          LDA #$C0 
  273.          STA NMIEN 
  274.          CLI  
  275.          JMP D2HAV 
  276. ; 
  277. NOTFN    LDA PORTB   ;NO, JUST BACK TO OS 
  278.          ORA #1 
  279.          STA PORTB 
  280.          LDA #$C0 
  281.          STA NMIEN 
  282.          CLI         ;INTS ENABLED 
  283. NONE     RTS         ;AND OUT 
  284. ; 
  285. DS2LO    JSR COPYDOWN ;LO FOUND 
  286.          LDA DRSADR 
  287.          STA DIHCL+1 ;REPLACE STAT CALL 
  288.          LDA DRSADR+1 
  289.          STA DIHCL+2 
  290.          LDA #$4C    ;JMP INSTRUCTION 
  291.          STA WRTDOS 
  292.          LDA # <ERDVDC ;TO INVALID CMD 
  293.          STA WRTDOS+1 
  294.          LDA # >ERDVDC ;DISABLES DOS WRITE 
  295.          STA WRTDOS+2 
  296. ; 
  297. D2HAV    CLC         ;EITHER, 
  298.          LDA SASA 
  299.          ADC # <RELEN ;ADD INSTALLED LENGTH 
  300.          STA SASA    ;TO END FMS VALUE 
  301.          LDA SASA+1 
  302.          ADC # >RELEN 
  303.          STA SASA+1 
  304.          JSR FMSINIT ;& REINIT FMS 
  305. ; 
  306. ******* FORMAT 'DISK' ******** 
  307. ; 
  308.          LDX RTCLKL 
  309. FMT      CPX RTCLKL 
  310.          BEQ FMT     ;WAIT VBL 
  311.          LDA #0 
  312.          STA NMIEN 
  313.          SEI         ;DISABLE INTS 
  314.          LDA PORTB 
  315.          AND #$E3 
  316.          PHA  
  317.          ORA #8 
  318.          STA PORTB   ;VTOC BANK 
  319.          LDX #0 
  320.          LDA $7200   ;1ST VTOC BYTE 
  321.          CMP #2 
  322.          BEQ VTST2 
  323.          INX  
  324. VTST2    LDA $7201   ;2ND 
  325.          CMP #$F7 
  326.          BEQ VTST3 
  327.          INX  
  328. VTST3    LDA $7202   ;3RD 
  329.          CMP #1 
  330.          BEQ VTSTN 
  331.          INX  
  332. VTSTN    PLA  
  333.          CPX #0 
  334.          BEQ FMTDN   ;OUT, PREVIOUSLY DONE 
  335. FLP1     STA PORTB 
  336.          LDA #$40 
  337.          STA BUFRL+1 
  338.          TAX  
  339.          LDA #0 
  340.          STA BUFRL 
  341.          TAY  
  342. FLP2     STA (BUFRL),Y ;CLEAR ALL DISK 
  343.          INY  
  344.          BNE FLP2 
  345.          INC BUFRL+1 
  346.          DEX  
  347.          BNE FLP2 
  348.          CLC  
  349.          LDA PORTB 
  350.          ADC #4 
  351.          PHA  
  352.          AND #$0C 
  353.          BEQ FCDON 
  354.